=SUMIF(C2:C21,">500") sums every value above 500. The criteria goes in double quotes with the operator inside.
Use ">=500" to include 500 itself. When the range you test and the range you sum are the same, the third argument can be left out entirely.
To test one column and sum another, add it: =SUMIF(B2:B21,">500",C2:C21). To take the threshold from a cell so you can change it without editing the formula, join with &: =SUMIF(C2:C21,">"&E1). For a second condition, switch to SUMIFS — note the sum range comes first there: =SUMIFS(C2:C32,B2:B32,"Electronics",C2:C32,">100").
The easiest way to sum greater-than values is to use the SUMIF function. Specify the range of values, then the value you want to use as the criterion for greater than. Let’s say you need to sum values greater than 10; use “>10” as the criterion in the function.
=SUMIF(range,”criteria”,sum_range)
Let’s learn with an example.

We have data with date, product name, and amount, and the idea is to sum all the amounts of $500 or more.
SUMIF for Sum Greater than Values
The SUMIF function can add numbers from a range that meet a specific condition. It works by looking at a range of cells to check if they meet the given criterion (like “greater than $500”).
=SUMIF(C2:C21,">=500",C2:C21)

You can enter the formula above in cell E2 to get the sum of values greater than 500.
Follow these steps:
- Type in =SUMIF( in cell E2 to start your formula.
- The first argument is the range over which the condition is evaluated. In our example, it’s C2:C21, where we have values. So, type C2:C21.
- The second argument is the condition. We need to sum values greater than or equal to 500, so it’s “>=500”, which means the function looks for values greater than or equal to 500. Enter “>=500”,.
- The third argument is the range from which to sum the values. Again, it’s C2:C21 in our example. Type C2:C21 and then a closing parenthesis.
- In the end, hit Enter to get the result.
If you need to change the criteria value from $500 to another value, edit the “>=500” part of the formula to use the new value (e.g., “>=1000” for values of $1000 or more). Use “>” instead of “>=” when you want to leave out the value itself, like “>500” for values above $500 only.
Note: As your sum range and criteria range are the same, you can skip specifying the sum range. And it will still return the sum of all the values greater than or equal to 500.
You can also use a cell reference to specify the criteria in the function. Join the operator with the cell using the ampersand (&), like in the following formula, where E1 has 500:
=SUMIF(C2:C21,">="&E1,C2:C21)
Make sure the cell reference stays outside the quotation marks. “>=E1” would compare the values with the text “E1”.

How Does This Formula Work?
In the example above, we used the same criteria, but we referred to a cell that has the number instead of typing the number in the formula.
So, we have that number in the cell, and in the criteria argument, we have combined it with the greater-than-or-equal-to operator.
The best part of using this method is that you can change the number in the cell without altering the formula itself.
One more thing you can change in the formula is to use an absolute reference for the criteria range. For this, you just need to add dollar signs before the cell reference, as in the following example.
=SUMIF($C$2:$C$21,">="&$E$1,$C$2:$C$21)
With absolute references, the ranges don’t move when you copy the formula to another cell.
SUMIFS for Sum Greater than Values in Excel
Let’s take an example of a different scenario where you need to manage inventory expenses and specifically want to track how much is being spent on high-cost items across various product categories.
You need to identify the total sales of products in the “Electronics” and “Clothing” categories that have sold for more than $100 each.

=SUMIFS(C2:C32, B2:B32, "Electronics", C2:C32, ">100")
This formula gives you the total for the “Electronics” category, where the sale is more than $100. To get the total for both “Electronics” and “Clothing”, put both categories in an array constant and wrap SUMIFS in SUM:
=SUM(SUMIFS(C2:C32,B2:B32,{"Electronics","Clothing"},C2:C32,">100"))
SUMIFS returns one total for each category, and SUM adds them together.
Hard Value Vs. Cell Reference in SUMIF/SUMIFS
When writing a formula, you can choose between hard values and cell references, each serving different purposes.
Hard values are actual numbers directly entered into your formula, like “>100” in a SUMIFS function. These values make your formula easy to write and read but less flexible because any change in criteria requires editing the formula itself.
On the other hand, using a cell reference (like B2 or C32) allows your formula to use the values in those cells dynamically. In this example, we have used the value from cell E1 as a criterion. Now, when you change the value in the cell from 500 to 600, it also changes that criterion in the formula.

Use SUMPRODUCT to SUM Values Greater than a Given Value
It is a bonus formula that I want to share with you. In this formula, instead of the SUMIF, you can use SUMPRODUCT to sum values greater than a value.

=SUMPRODUCT(--(C2:C21>=500), C2:C21)
In this formula, “C2:C21>=500” creates an array of Boolean values (TRUE or FALSE) where each value in the range C2:C21 is compared to 500. It’s TRUE if the condition is met (the value is greater than or equal to 500); otherwise, it is FALSE. And then, the double hyphen (–) converts the array of TRUE/FALSE values into 1s and 0s. TRUE becomes 1, and FALSE becomes 0.
Then, SUMPRODUCT multiplies each value of the first array (1s and 0s) with the corresponding values in the second array (C2:C21). Since multiplying by 1 leaves the original value unchanged and multiplying by 0 results in 0, this effectively filters out the values below 500.
Sum Values Greater than a Date
Dates are numbers in Excel, so the same idea works with dates too. The following formula sums the amounts in C2:C21 where the date in column A is after 1 January 2024. Using the DATE function keeps the formula working whatever date format your system uses:
=SUMIF(A2:A21,">"&DATE(2024,1,1),C2:C21)
Why SUMIF Greater Than Might Give a Wrong Total
- Numbers stored as text: SUMIF and SUMPRODUCT skip them, so the total is lower than expected. Convert them to numbers first (Data ➜ Text to Columns ➜ Finish is a quick way).
- > vs >=: “>500” leaves out the values that are exactly 500, while “>=500” includes them.
- Operator outside the quotes: the operator must be inside the quotation marks, like “>500” or “>”&E1, not >”500”.
Frequently Asked Questions
How do I sum values between two numbers?
Use SUMIFS with two conditions on the same range, one with “>=” and one with “<=”:
=SUMIFS(C2:C21,C2:C21,">=500",C2:C21,"<=1000")
Can I sum one column based on values greater than in another column?
Yes. Use the column with the condition as the range and the other column as sum_range. The following formula sums column C where column B is more than 10:
=SUMIF(B2:B21,">10",C2:C21)
Does SUMIF greater than work with negative numbers?
Yes. For example, “>-100” sums all the values above -100, including the positive ones, and “>0” sums only the positive values.
Written by
Puneet Gogia
Microsoft MVP — Excel · Founder, Excel Champs
Twelve years of teaching Excel, and a decade before that using it as a data analyst. Every tutorial here is written from a file I actually built.