Excel has UPPER, LOWER and PROPER but no sentence-case function, so you build it. For a single sentence, capitalise the first character and lowercase the rest: =UPPER(LEFT(A1,1))&LOWER(RIGHT(A1,LEN(A1)-1)). That’s all it takes when the cell holds one sentence.
For a cell containing several sentences, the trick is to hide the spaces so PROPER can’t capitalise every word, then put them back: =SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(PROPER(SUBSTITUTE(SUBSTITUTE(LOWER(A1),". ","9z9")," ","zxz")),"9Z9",". "),"zxz"," "),"Zxz"," "). The final SUBSTITUTE for the capitalised “Zxz” is what handles text containing commas — without it, “yes, please” comes back as “Yes,Zxzplease”.
Two limits worth knowing: an empty cell returns #VALUE! because LEN(A1)-1 goes negative, so wrap it in =IFERROR(...,""), and both formulas lowercase proper nouns and the word “I” along with everything else, so names need fixing by hand afterwards.
In Excel, we have three specific functions to convert text from one case to another. But there is another case for which we don’t have any function or any other option.
That’s ⇢ Sentence Case
What Is Sentence Case?
In sentence case, the first letter of the first word of a sentence is a capital letter, and the rest of the letters of the first word and all the other words are in lowercase.

Now, the question is: how can we convert normal text to sentence case in Excel if we don’t have any particular function or option?
The answer is simple. We can create a formula by combining other text functions. So today, in this post, I’d like to share with you a simple formula that you can use to convert normal text to sentence case in Excel.
Let’s get started and download this file from here to follow along.
Convert to Sentence Case in Excel
To create a formula for sentence case, we need to use five different text functions. Let’s say your text is in cell A1; then the formula will be:
=UPPER(LEFT(A1,1))&LOWER(RIGHT(A1,LEN(A1)-1))
There’s one small problem with this formula: if A1 is empty, LEN(A1)-1 is -1, and RIGHT returns the #VALUE! error. Using MID instead of RIGHT gives the same result and simply returns a blank for an empty cell:
=UPPER(LEFT(A1,1))&LOWER(MID(A1,2,LEN(A1)))
And if your text may start with a space, add TRIM, so the first real letter becomes the capital one:
=UPPER(LEFT(TRIM(A1),1))&LOWER(MID(TRIM(A1),2,LEN(A1)))
How it Works
To understand this formula, we need to split it into two parts.

In the first part, the LEFT function returns the first character, and then the UPPER function converts it into uppercase.

In the second part, we will convert the rest of the text to lowercase as we need the rest of the letters in lowercase for sentence case.

And finally, this combination returns the text in sentence case.

Yes, that’s it.
Convert to Sentence Case for More than One Sentence
The formula we have learned above is simple and easy to apply. But, do you have the same thought in your mind that I have right now?
What will we do if there is more than one sentence in a cell? In this situation, the above formula is of no use, as it only capitalizes the first letter of the cell.
We need a different formula that can convert text into sentence case when we have more than one sentence (here, the text is in cell C12).
=SUBSTITUTE(SUBSTITUTE(PROPER(SUBSTITUTE(SUBSTITUTE(LOWER(C12),". ","9z9")," ","zxz")),"9Z9",". "),"zxz"," ")

How it Works
So, you want to learn how this formula works? Right? Well, you need to hold your nerves and stay with me for a minute. We need to split this formula into three different parts as I have done below.
In the first part, with the LOWER function and two SUBSTITUTE functions, we have converted the text into lowercase, replaced the dot and space between two sentences with “9z9”, and replaced all the other spaces between words with “zxz”.

At this point, we don’t have any space in our text. So far so good.
In the second part, we have converted the entire text into proper case using the PROPER function. As there are no spaces left, PROPER treats each sentence as one word and only capitalizes its first letter (and the letter after each “9”).

A secret you need to learn: Whenever you convert text into proper case and you have a number in that text, the function will treat the number as the end of a word and capitalize the letter after it. Look at the below example.

In the third part, we have again used two SUBSTITUTE functions to replace “zxz” with a space and “9Z9” with a dot and space.

In this way, we have converted our multiple-sentence text into actual sentence case text.
There’s one limit to keep in mind. As PROPER also capitalizes a letter that comes right after a number, a word like “2nd” becomes “2Nd” with this formula. And as it converts everything else to lowercase first, names and words like “Excel” or “I” also become lowercase, so check the result if your text has them.
Conclusion
Sometimes we use Excel to type some sort of text, and there is a chance we type it in the wrong case. And if you know how to convert text into sentence case, you can correct your text easily.
If you have a sentence that ends with a question mark instead of a dot, then you can add one more pair of SUBSTITUTE functions for “? ” in the same way, and the rest of the formula will be the same. I hope this formula tip will help you in your work. Now, tell me one thing.
Do you have any other method to do this text conversion?
Share your views with me in the comment section; I would love to hear from you. And, please don’t forget to share this tip with your friends.
Use Microsoft Word to Change to Sentence Case
If you only need to do this once, and you don’t want to use a formula, Word has a built-in option for sentence case:
- First of all, copy the cells from Excel and paste them into a Word document.
- After that, select the text and go to Home ➜ Change Case (the Aa button) ➜ Sentence case.
- In the end, copy the text back and paste it into Excel.
Frequently Asked Questions
Is there a SENTENCE function in Excel?
No. Excel has UPPER, LOWER and PROPER, but no function for sentence case, which is why you need one of the formulas above.
How do I replace the original text with the result?
Copy the formula cells, then use Paste Special ➜ Values over the original cells (or Ctrl + Alt + V, then V). After that, you can delete the formula column.
Can Flash Fill convert text to sentence case?
Sometimes. Type the first one or two results by hand next to your data and press Ctrl + E. Flash Fill guesses the pattern, so check the results, especially for cells with more than one sentence.
Is there a way that this can be done using Power Query?
Yes.
This is where your blog is unique. you give practical stuff never heard of elsewhere and provide a lucid explanation with example files.
Though nothing too advanced which is excel guru level but useful stuff that others wouldnt have thought of
Puneet, nice formula.
Problem is that it does not play well with punctuation and other non-alphabet characters (eg , . ] 🙂
Example “yes please” correctly returns “Yes please” but “yes, please” returns “Yes,Zxzplease”
It can be corrected with a further SUBSTITUTE(“Zxz”,” “) in the formula
Paul :Zxz)
Paul, can you restate the entire formula with the added substitute to fix the comma problem? I really need the formula to work with commas in sentences, and I can’t figure out how/where to add the extra substitute you suggested. Additionally, can we add another substitute to get the formula to handle apostrophes? If yes, what would that formula look like?
Kudos… Very creative especially to convert multiple sentences..
It was a really show, thanks
Good explanation and nice formula Puneet. Please check ASAP utilities Addin for Excel (free for non commercial use) in the option Text (collection of tools number 2 to 7) specially 7th item. Many options and works on many including filtered cells and saves lot of time. No need to use functions or formulas by the user.
Nice formula Puneet ! Very creative!